\*Please note that IRF results may change according to the configuration of the computer.

compute p=1

\*

\* Number of periods for impulse responses

\*

compute h=19

\*

\* Number of outer draws for initial conditions

\*

compute nhist=300

\*

\* Number of inner bootstrap draws. (The paper does 10000 at this point.

\* However, the difference due to the extra simulations isn't noticeable).

\*

compute ndraws=100

\*

\* Scale-ups of the shock

\*

dec vect scales(4)

compute scales=||1.0||

dec vect[series] yirf(%size(scales))

dec vect[strings] irflabels(%size(scales))

compute irflabels=||"1 s.d.","2 s.d.","4 s.d.","10 s.d."||

\*

\*

open data "2 - Kopya.rat"

cal(m) 2000:1

data(format=rats,compact=last) 2000:01 2017:2

\*

set x = fsi

set y = brazil

\*

set xplus = %max(0.0,x)

\*

\* Estimate the two equations. The "X" equation uses only lags of X and

\* Y. The Y equation uses both the X and X+ series and also includes the

\* current values of each.

\*

\* Save the standard deviation of the residuals for the X series for use

\* in sizing shocks.

\*

linreg(define=xeq) x / ux

# constant x{1 to p} y{1 to p}

compute sigmax=sqrt(%sigmasq)

\*

linreg(define=yeq) y / uy

# constant x{0 to p} y{1 to p} xplus{0 to p}

\*

\* Range of residuals as source for bootstrapping

\*

compute bstart=%regstart(),bend=%regend()

\*

\* Range of simulated forecasts

\*

compute hstart=%regend()+1,hend=%regend()+h

\*

\* Range of data for blocks of pre-sample values

\*

compute dstart=%regstart()-p,dend=%regend()

\*

\* Definitional identities for XPLUS and for the level (rather than

\* difference) of the real activity variable.

\*

frml xplusdef xplus = %max(0.0,x)

frml(identity) lydef ly = ly{1}+y

\*

\* The values of this don't matter since everything is done as deviations

\* from the base value.

\*

set ly dstart hend = 0.0

\*

\* Because the Y equation includes the current value of XPLUS, it's

\* necessary to arrange the model so XPLUS is solved before Y.

\*

group asymmvar xeq xplusdef yeq lydef

\*

\* Make copies of data for bootstrapping

\*

set xraw dstart dend = x

set yraw dstart dend = y

\*

do i=1,%size(scales)

compute delta=scales(i)\*sigmax

\*use compute delta=-scales(i)\*sigmax for negative shocks

set yirf(i) hstart hend = 0.0

set zeros hstart hend = 0.0

\*

do hist=1,nhist

\*

\* Draw block of length p for initial conditions

\*

boot(block=p) ientries hstart-p hstart-1 dstart dend

set x hstart-p hstart-1 = xraw(ientries(t))

set y hstart-p hstart-1 = yraw(ientries(t))

set xplus hstart-p hstart-1 = %max(x,0)

\*

do draw=1,ndraws

\*

\* Draw random entries for residuals for forecast period

\*

boot entries hstart hend bstart bend

set xpath hstart hend = ux(entries(t))

set ypath hstart hend = uy(entries(t))

\*

\* Do FORECAST with simulated paths throughout

\*

forecast(model=asymmvar,from=hstart,to=hend,results=base,paths,noprint)

# xpath zeros ypath

\*

\* Do FORECAST with first period X shock replaced by delta

\*

set xpath hstart hend = %if(t==hstart,delta,ux(entries(t)))

forecast(model=asymmvar,from=hstart,to=hend,results=wshock,paths,noprint)

# xpath zeros ypath

\*

\* Add the gap for the accumulated Y response (4th variable) to IRF(i)

\*

set yirf(i) hstart hend = yirf(i)+(wshock(4)-base(4))

end do draw

end do hist

\*

set yirf(i) hstart hend = (yirf(i)/(nhist\*ndraws))/scales(i)

end do i

\*

graph(series=yirf,key=upright,klabels=irflabels,number=0,footer=$

"name your figure")